技术标签: batch-file arguments
我需要在运行时将ID和密码传递给批处理文件,而不是将其硬编码为文件。
命令行如下所示:
test.cmd admin P@55w0rd > test-log.txt
无需使其复杂化。 例如,它只是命令%1%2的参数,
@echo off
xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z
echo copied %1 to %2
pause
“暂停”显示批处理文件已完成的操作,并等待您按ANY键。 将其另存为Windows文件夹中的xx.bat。
要使用它,请键入,例如:
xx c:\f\30\*.* f:\sites\30
该批处理文件处理所有必要的参数,例如仅复制文件,更新文件等。自Windows之前我就使用它。 如果要查看正在复制的文件名,请省略Q
参数。
要在命令行中引用set变量,您将需要使用%a%
这样,例如:
set a=100
echo %a%
rem output = 100
注意:这适用于Windows 7专业版。
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue
注意:如果将%1
括在引号本身中,则如果"%1"==""
会引起问题。
在这种情况下,请使用IF [%1]==[]
或者仅在NT 4(SP6)和更高版本中使用IF "%~1"==""
。
是的,只是在使用if
和for
和gang时不要忘记使用%%1
类的变量。
如果您忘记了双精度%
,那么您将用(可能为null)命令行参数替换,并且会收到一些非常令人困惑的错误消息。
另一个有用的技巧是使用%*
表示“全部”。 例如:
echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*
运行时:
test-command admin password foo bar
上面的批处理文件将运行:
fake-command /u admin /p password admin password foo bar
我的语法可能有些错误,但这是一般的想法。
如果要智能处理丢失的参数,可以执行以下操作:
IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1
:No1
ECHO No param 1
GOTO End1
:No2
ECHO No param 2
GOTO End1
:End1
FOR %%A IN (%*) DO (
REM Now your batch file handles %%A instead of %1
REM No need to use SHIFT anymore.
ECHO %%A
)
这会循环引用或不引用批处理参数(%*),然后回显每个参数。
让我们保持简单。
这是.cmd文件。
@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%
这是从命令行进行的3个调用。
C:\Users\joeco>echo_3params 1abc 2 def 3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def
C:\Users\joeco>echo_3params 1abc "2 def" "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"
C:\Users\joeco>echo_3params 1abc '2 def' "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'
C:\Users\joeco>
我编写了一个简单的read_params脚本,可以将其称为函数(或外部.bat
),并将所有变量放入当前环境中。 它不会修改原始参数,因为正在使用原始参数的副本call
该函数。
例如,给出以下命令:
myscript.bat some -random=43 extra -greeting="hello world" fluff
myscript.bat
将能够在调用函数后使用变量:
call :read_params %*
echo %random%
echo %greeting%
功能如下:
:read_params
if not %1/==/ (
if not "%__var%"=="" (
if not "%__var:~0,1%"=="-" (
endlocal
goto read_params
)
endlocal & set %__var:~1%=%~1
) else (
setlocal & set __var=%~1
)
shift
goto read_params
)
exit /B
局限性
-force
。 您可以使用-force=true
但是我想不了一种方法来允许空白值,而无需提前知道没有值的参数列表。 变更日志
-
与其他命令行参数一起使用。 最近有一个朋友问我有关此主题的信息,所以我认为我应该发布如何处理批处理文件中的命令行参数。
如您所见,该技术会产生一些开销,但是它使我的批处理文件非常容易理解和快速实现。 以及支持以下结构:
>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]
它的关键是具有:init
, :parse
和:main
函数。
用法示例
>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
USAGE:
test.bat [flags] "required argument" "optional argument"
/?, --help shows this help
/v, --version shows the version
/e, --verbose shows detailed output
-f, --flag value specifies a named parameter value
>template.bat <- throws missing argument error
(same as /?, plus..)
**** ****
**** MISSING "REQUIRED ARGUMENT" ****
**** ****
>template.bat -v
1.23
>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument: "arg1"
UnNamedOptionalArg: not provided
NamedFlag: not provided
>template.bat --flag "my flag" arg1 arg2
UnNamedArgument: "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag: "my flag"
>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument: "argument #1"
UnNamedOptionalArg: "second"
NamedFlag: "my flag"
template.bat
@::!/dos/rocks
@echo off
goto :init
:header
echo %__NAME% v%__VERSION%
echo This is a sample batch file template,
echo providing command-line arguments and flags.
echo.
goto :eof
:usage
echo USAGE:
echo %__BAT_NAME% [flags] "required argument" "optional argument"
echo.
echo. /?, --help shows this help
echo. /v, --version shows the version
echo. /e, --verbose shows detailed output
echo. -f, --flag value specifies a named parameter value
goto :eof
:version
if "%~1"=="full" call :header & goto :eof
echo %__VERSION%
goto :eof
:missing_argument
call :header
call :usage
echo.
echo **** ****
echo **** MISSING "REQUIRED ARGUMENT" ****
echo **** ****
echo.
goto :eof
:init
set "__NAME=%~n0"
set "__VERSION=1.23"
set "__YEAR=2017"
set "__BAT_FILE=%~0"
set "__BAT_PATH=%~dp0"
set "__BAT_NAME=%~nx0"
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedOptionalArg="
set "NamedFlag="
:parse
if "%~1"=="" goto :validate
if /i "%~1"=="/?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="-?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="--help" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="/v" call :version & goto :end
if /i "%~1"=="-v" call :version & goto :end
if /i "%~1"=="--version" call :version full & goto :end
if /i "%~1"=="/e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="-e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--verbose" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--flag" set "NamedFlag=%~2" & shift & shift & goto :parse
if not defined UnNamedArgument set "UnNamedArgument=%~1" & shift & goto :parse
if not defined UnNamedOptionalArg set "UnNamedOptionalArg=%~1" & shift & goto :parse
shift
goto :parse
:validate
if not defined UnNamedArgument call :missing_argument & goto :end
:main
if defined OptVerbose (
echo **** DEBUG IS ON
)
echo UnNamedArgument: "%UnNamedArgument%"
if defined UnNamedOptionalArg echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
if not defined UnNamedOptionalArg echo UnNamedOptionalArg: not provided
if defined NamedFlag echo NamedFlag: "%NamedFlag%"
if not defined NamedFlag echo NamedFlag: not provided
:end
call :cleanup
exit /B
:cleanup
REM The cleanup function is only really necessary if you
REM are _not_ using SETLOCAL.
set "__NAME="
set "__VERSION="
set "__YEAR="
set "__BAT_FILE="
set "__BAT_PATH="
set "__BAT_NAME="
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedArgument2="
set "NamedFlag="
goto :eof
制作一个新的批处理文件(例如:openclass.bat),并将此行写入文件中:
java %~n1
然后将批处理文件放在(例如)system32文件夹中,转到您的Java类文件,右键单击“属性”,“打开方式为...”,然后找到您的批处理文件,将其选中,就是这样...
这个对我有用。
PS:关闭Java类时,找不到关闭cmd窗口的方法。 目前...
受@Jon 在其他地方给出的答案的启发,我设计了一种更通用的算法来提取命名参数,可选值和开关。
假设我们要实现实用程序foobar
。 它需要一个初始命令。 它有一个可选参数--foo
,它带有一个可选值(当然不能是另一个参数); 如果缺少该值,则默认为default
。 它还具有一个可选参数--bar
,该参数采用必需的值。 最后,它可以带一个标志--baz
,不允许值。 哦,这些参数可以按任何顺序排列。
换句话说,它看起来像这样:
foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]
这是一个解决方案:
@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson
SET CMD=%~1
IF "%CMD%" == "" (
GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=
SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
SHIFT
IF NOT "%ARG%" == "" (
IF NOT "%ARG:~0,2%" == "--" (
SET FOO=%ARG%
SHIFT
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE IF "%PARAM%" == "--bar" (
SHIFT
IF NOT "%ARG%" == "" (
SET BAR=%ARG%
SHIFT
) ELSE (
ECHO Missing bar value. 1>&2
ECHO:
GOTO usage
)
) ELSE IF "%PARAM%" == "--baz" (
SHIFT
SET BAZ=true
) ELSE IF "%PARAM%" == "" (
GOTO endargs
) ELSE (
ECHO Unrecognized option %1. 1>&2
ECHO:
GOTO usage
)
GOTO args
:endargs
ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
ECHO Baz
)
REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof
:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
SETLOCAL
以便变量不会逸出到调用环境中。 SET FOO=
。 %~1
删除引号。 IF "%ARG%" == ""
而不要使用IF [%ARG%] == []
因为[
和]
根本不会播放以空格结尾的值。 SHIFT
内部IF
块,当前ARGS比如%~1
没有得到,因为当他们决定更新IF
解析。 您可以在IF
块中使用%~1
和%~2
IF
,但这会造成混淆,因为您有SHIFT
。 为了清楚起见,您可以将SHIFT
放在块的末尾,但这可能会迷失和/或使人们感到困惑。 因此,最好在块外“捕获” %~1
和%~1
。 IF NOT "%ARG:~0,2%" == "--"
。 SHIFT
。 SET FOO=%DEFAULT_FOO%
,但替代方法是在IF NOT "%ARG%" == ""
块外添加IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%
。 但是,由于这仍是里面的IF "%PARAM%" == "--foo"
块中, %FOO%
的值将被评估,并设置之前,你从来没有入过块,所以你永远不会发现, 无论是--foo
参数存在,并且还使得%FOO%
值丢失。 ECHO Missing bar value. 1>&2
ECHO Missing bar value. 1>&2
将错误消息发送到stderr。 ECHO:
或其中一种变体。 简单的解决方案(即使问题很旧)
Test1.bat
echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause
CallTest1.bat
call "C:\Temp\Test1.bat" pass123
输出
YourLocalPath>call "C:\Temp\test.bat" pass123
YourLocalPath>echo off
"Batch started"
"arg1 is pass123"
YourLocalPath>pause
Press any key to continue . . .
其中YourLocalPath是当前目录路径。
为了简单起见,将命令参数存储在变量中,并使用变量进行比较。
它不仅易于编写,而且易于维护,因此,如果以后有人或长时间阅读脚本后,将易于理解和维护。
内联编写代码:请参阅其他答案。
要使用循环,请使用纯批处理获取所有参数:
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
)
goto :eof
您的代码已准备就绪,可以在需要的地方使用参数编号进行处理,例如...
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift
)
fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
使用%1,%2,...%9或%*,可以轻松访问批处理参数。
但前提是内容简单。
对于诸如"&"^&
类的复杂内容,没有简单的方法,因为无法访问%1而不会产生错误。
set var=%1
set "var=%1"
set var=%~1
set "var=%~1"
线扩大到
set var="&"&
set "var="&"&"
set var="&"&
set "var="&"&"
每行都会失败,因为&
之一在引号之外。
可以通过从临时文件中读取该参数的标记版本来解决。
@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
for %%a in (1) do (
set "prompt="
echo on
for %%b in (1) do rem * #%1#
@echo off
) > param.txt
ENDLOCAL
for /F "delims=" %%L in (param.txt) do (
set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
诀窍是在rem
语句之后启用echo on
并扩展%1(也可用于%2 .. %*
)。
因此,即使"&"&
也可以在不产生错误的情况下回显,如前所述。
但是要能够重定向echo on
的输出,您需要两个for循环。
多余的字符* #
用于防止诸如/?
内容/?
(将显示REM
的帮助)。
或者,即使在rem
之后,行尾的插入符号^也可以用作多行字符。
然后仔细阅读文件中的rem参数输出。
FOR / F应该在延迟扩展关闭的情况下工作,否则内容应带有“!” 将被摧毁。
在删除param1
的多余字符之后,您就知道了。
为了安全使用param1
,请启用延迟扩展。
在批处理文件中
set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%
%1和%2分别返回第一个和第二个参数值。
然后在命令行中通过thestrmt
Directory> batchFileName admin P@55w0rd
输出将是
admin
P@55w0rd
这是我的操作方式:
@fake-command /u %1 /p %2
该命令如下所示:
test.cmd admin P@55w0rd > test-log.txt
%1
适用于第一个参数, %2
(这是棘手的部分)适用于第二个参数。 通过这种方式,您最多可以传递9个参数。
在多媒体通信领域,MRCP(Media Resource Control Protocol)协议被广泛用于控制语音识别和合成等媒体资源。UniMRCP是一个开源的MRCP实现,提供了客户端和服务端的库。UmcFramework是一个基于UniMRCP客户端库的示例应用程序框架,它帮助开发者快速集成和测试MRCP客户端功能。本文将详细介绍如何使用UmcFramework和unimrcpclient.xml配置文件连接到多个SIP设置,以及如何用C代码进行示例说明。
文章浏览阅读3k次。报错:java.net.ProtocolException: Server redirected too many times (20)1.没有检查到cookie,一直循环重定向。解决:CookieHandler.setDefault(new CookieManager(null, CookiePolicy.ACCEPT_ALL));URL url = new URL(url); ..._java.net.protocolexception: server redirected too many times (20)
文章浏览阅读4.1k次。问题这是部分报错信息2019-07-11 14:03:34.283 WARN [restartedMain][DirectJDKLog.java:175] - Failed to scan [file:/D:/repo/org/apache/derby/derby/10.14.2.0/derbyLocale_ja_JP.jar] from classloader hierarchyjava...._failed to scan from classloader hierarchy
文章浏览阅读2.8k次,点赞3次,收藏7次。在MATLAB中,ones函数用于创建一个指定大小的由1组成的矩阵或数组。_matlab中ones函数
文章浏览阅读3.9w次,点赞2次,收藏9次。 在使用电脑办公过程中,安装应用程序时难免遇到无法安装或者无法正常启动的问题,这对我们使用电脑带来了诸多不便。那遇到应用程序无法正常启动的问题要如何解决呢?相信大家肯定都是十分疑问的,每次都是只能忍痛重新安装软件。今天,小编就和大家探讨下应用程序无法正常启动的解决方法,帮助大家排忧解难。0xc000007b电脑图解1 第一种方案:SFC检查系统完整性来尝试修复丢失文件 1、打开电脑搜索输入cmd.exe,选择以管理员身份运行,跳出提示框时选择继续。0xc000007b电脑图解2_photoshop应用程序无法正常启动0xc000007b。请单击“确认”关闭应用程序。
文章浏览阅读396次。1、概念 REDO LOG是Oracle为确保已经提交的事务不会丢失而建立的一个机制。实际上REDO LOG的存在是为两种场景准备的:实例恢复(INSTANCE RECOVERY);介质恢复(MEDIA RECOVERY)。 实例恢复的目的是在数据库发生故障时,确保BUFFER CACHE中的数据不会丢失,不会造成数据库的..._oracle 实例恢复和介质恢复
文章浏览阅读418次。概述说明CAS内置了密码找回和密码修改的功能; 密码找回功能是,系统会吧密码重置的连接通过邮件或短信方式发送给用户,用户点击链接后就可以重置密码,cas还支持预留密码重置的问题,只有回答对了,才可以重置密码;系统可配置密码重置后,是否自动登录; 密码修改功能是,用户登录后输入新密码即可完成密码修改。安装步骤`1. 首先,搭建好cas sso server您需要按..._修改cas默认用户密码
文章浏览阅读141次。之前几章演示的熔断,降级 都是 RestTemplate + Ribbon 和RestTemplate + Hystrix ,但是在实际开发并不是这样,实际开发中都是 Feign 远程接口调用。Feign + Hystrix 演示: eruka(略)order 服务工程: pom.xml<?xml version="1.0" encoding="U..._this is order 服务工程
文章浏览阅读3.4k次,点赞35次,收藏43次。学习率是影响目标检测精度和速度的重要因素之一。合适的学习率调度策略可以加速模型的收敛和提高模型的精度。在YOLOv7算法中,可以使用基于余弦函数的学习率调度策略(Cosine Annealing Learning Rate Schedule)来调整学习率。
文章浏览阅读4k次,点赞4次,收藏9次。 linux中进程退出函数:exit()和_exit()的区别(1)_exit()执行后立即返回给内核,而exit()要先执行一些清除操作,然后将控制权交给内核。(2)调用_exit函数时,其会关闭进程所有的文件描述符,清理内存以及其他一些内核清理函数,但不会刷新流(stdin, stdout, stderr ...). exit函数是在_exit..._linux结束进程可以用哪些函数,它们之间有何区别?
文章浏览阅读134次。select 5000/10000.0 --想变成0.5select 5500/10000.0 --想变成0.55select 5550/10000.0 --想变成0.555select 5555/10000.0 --想变成0.5555其结果分别为:0.5000000 0.5500000 0.5550000 0.5555000一、如果想去掉数字5后面多余的0 ,需要转化一下:selec..._sql server 去小数 0
文章浏览阅读3.1k次。例一:import { Injectable } from '@angular/core';import { Observable } from 'rxjs';import { User } from "./model/User";import { map } from 'rxjs/operators';import { Http, Response, Headers, RequestOp..._angular6,requestoptions改成了什么